; タコメーター(Tachometer)
if = time<=13000
	; 昼用の計器
	DrawTexture = super_duty_hud,  144, 21,  64,64,  256,  0, 128,128
	DrawTexture = super_duty_hud,  168, 21,  16,64,  384,  0,  32,128, Throttle*150-100
Endif

if = time> 13000
	; 夜間用の計器
	DrawTexture = super_duty_hud,  144, 21,  64,64,  256,128, 128,128
	DrawTexture = super_duty_hud,  168, 21,  16,64,  416,  0,  32,128, Throttle*150-100
Endif

; 燃料(Fuel)
if = time<=13000
	; 昼用の計器
	DrawTexture = super_duty_hud, -207, 83,   32,32,  00,128, 64,64
	DrawTexture = super_duty_hud, -199, 84,   16,48,  64,160, 32,96, fuel*92-45
Endif

if = time> 13000
	; 夜間用の計器
	DrawTexture = super_duty_hud, -207, 83,   32,32,  00,192, 64,64
	DrawTexture = super_duty_hud, -199, 84,   16,48,  96,160, 32,96, fuel*92-60
Endif

; 燃料の低下を警告表示
If = low_fuel
	DrawTexture = hud, 40,-85, 16,16,  0,0,  32,32
	Color = 0xFFDF0408
	DrawString  = 56,-80, "%s key", KEY_GUI
EndIf

; インベントリ数を表示
If = inventory > 0
	Color = 0xCF1FFF1F
	DrawString = 120, -80, "Inventory [ %d ]", INVENTORY
Endif

; 色設定(Current Color)
Color = 0xFF58ffee
; 時計(time)
; マイクラ内の時間と分を表示
DrawCenteredString = 0, 40, " [ %02d:%02d ]", MC_THOR, MC_TMIN

; 色設定(Current Color)
Color = 0xFF28d448
; 座標(Position)
DrawString = -205, 20, "X: %+.1f", pos_X
DrawString = -205, 30, "Y: %+.1f", pos_Y
DrawString = -205, 40, "Z: %+.1f", pos_Z
DrawString = -150, 20, "[%+.2f]",  motion_X
DrawString = -150, 30, "[%+.2f]",  motion_Y
DrawString = -150, 40, "[%+.2f]",  motion_Z

; 耐久値(HP)
; HPが20%を超えている場合は白(0xFFffffff)、HPが20%以下の場合は赤(0xFFDF0408)
Color = hp_rto>0.2? 0xFFffffff: 0xFFDF0408
DrawTexture = hud, 144, 95, 64,20, 128,64, 128,20
DrawString  = 150,    97, "%3.0f", HP_PER
DrawString  = 150+26, 97, "/ 100", HP_PER
DrawRect    = 146, 107, hp_rto*60, 6

Color = 0xFFffffff
If = free_look==1
	DrawString = -90, -80, "FREE LOOK"
Endif

If = cam_mode==1
	DrawString = 30, 50, "NIGHT VISION"
Endif
If = cam_mode==2
	DrawString = 30, 50, "THERMAL VISION"
Endif

; 弾数, 残弾 背景 (Ammo background)
DrawTexture = plane_hud_wwii, -208, 57,  62,10,  128,192, 128,20
; 武器名 (Weapon name background)
DrawTexture = plane_hud_wwii, -208, 68, 106,10,  128,192, 128,20

; 弾数, 残弾 (Ammo) リロード中でなければ白、リロード中であれば赤
Color = reloading==0? 0xCFFFFFFF: 0xFFDF0408
DrawString = -207, 58, "%s",  WPN_AMMO
DrawString = -181, 58, "/",   WPN_AMMO
DrawString = -172, 58, "%s",  WPN_RM_AMMO
; 武器名 (Weapon name)
DrawString = -207, 69, "%s",  WPN_NAME

; 銃身の熱量タイプの場合(Heat)
If = is_heat_wpn==1
	Color = 0xCFFFFFFF
	DrawRect = -145, 57, 43, 10
	Color = 0xCFAFAFAF
	DrawRect = -144, 58, 41, 8
	Color = 0xFFDF0408
	DrawRect = -144, 58, 41*wpn_heat, 8
EndIf

If = auto_pilot==1
	DrawString = 50, 0, "Auto Pilot"
Endif